FireFox и подгружаемые jpeg @ DeForum.ru

0 Сообщения: 137 Зарегистрирован: 10.02.05

Вот натолкнулся на такую проблему...
есть flash который подгружает три картинки (данные берет из xml)
и выводит их на сцену...
в IE картинки выводятся так как им сказали..
а вот в ff они в разнобой лепятся.

вот код который выводит картинки. понимаю что он корявый в плане этики програминга, как говортся только учусь.

Спасибо за помощь.

Код:

var loadListener:Object = new Object ();
loadListener.onLoadComplete = function (target_mc:MovieClip, httpStatus:Number):Void 
{
   // y coord
   pic1._y = 20.9;
   pic2._y = 20.9;
   pic3._y = 20.9;
   // x coord
   pic1._x = 0;
};
loadListener.onLoadInit = function (target_mc:MovieClip):Void 
{
   pic1._height = 192.3;
   pic1._xscale = pic1._yscale;
   pic2._height = 192.3;
   pic2._xscale = pic2._yscale;
   pic3._height = 192.3;
   pic3._xscale = pic3._yscale;
   if (pic1._width > 208.5)
   {
      pic1._width = 208.5;
      pic1._yscale = pic1._xscale;
   }
   if (pic2._width > 208.5)
   {
      pic2._width = 208.5;
      pic2._yscale = pic2._xscale;
   }
   if (pic3._width > 208.5)
   {
      pic3._width = 208.5;
      pic3._yscale = pic3._xscale;
   }
   pic1._x = 0;
   pic2._x = 208;
   pic3._x = 416;
   if (pic1._width < 208.5)
   {
      pic1._x += 40;
   }
   if (pic2._width < 208.5)
   {
      pic2._x += 40;
   }
   if (pic3._width < 208.5)
   {
      pic3._x += 40;
   }
   
};
var mcLoader:MovieClipLoader = new MovieClipLoader ();
mcLoader.addListener (loadListener);
var mc:MovieClip = this.createEmptyMovieClip ("pic1", this.getNextHighestDepth ());
mcLoader.loadClip (_root.pic1Img, pic1);
var mc:MovieClip = this.createEmptyMovieClip ("pic2", this.getNextHighestDepth ());
mcLoader.loadClip (_root.pic2Img, pic2);
var mc:MovieClip = this.createEmptyMovieClip ("pic3", this.getNextHighestDepth ());
mcLoader.loadClip (_root.pic3Img, pic3);
stop ();

Можно так попобывать. По идеи это тоже самое, только болие направлено на общий случай

Код:

var loadListener:Object = new Object();
loadListener.onLoadComplete = function(target_mc:MovieClip, httpStatus:Number):Void
{
    // y coord
    target_mc._y = 20.9;
    // x coord
    target_mc._x = 0;
};
loadListener.onLoadInit = function(target_mc:MovieClip):Void
{
    target_mc._height = 192.3;
    target_mc._xscale = target_mc._yscale;
    if (target_mc._width>208.5)
    {
        target_mc._width = 208.5;
        target_mc._yscale = target_mc._xscale;
    }
    target_mc._x = (Number(target_mc._name.charAt(target_mc._name.length-1))-1)*208;
    if (target_mc._width < 208.5) target_mc._x += 40;
};
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(loadListener);
var pic1:MovieClip = this.createEmptyMovieClip("pic1", this.getNextHighestDepth());
var pic2:MovieClip = this.createEmptyMovieClip("pic2", this.getNextHighestDepth());
var pic3:MovieClip = this.createEmptyMovieClip("pic3", this.getNextHighestDepth());
mcLoader.loadClip(_root.pic1Img, pic1);
mcLoader.loadClip(_root.pic2Img, pic2);
mcLoader.loadClip(_root.pic3Img, pic3);
this.stop();

0 Сообщения: 137 Зарегистрирован: 10.02.05

Спасибо вопрос решен...

проблема была в том что почемуто в IE и в FF картинки подкачивались в разном порядке.. а код был написан коряво.. и не учитывал варианты что первой будет загружатся не первая картинка )

DeДверь
Логин:
Пароль:
	Автологин