обращение к функции в классе изнутри объекта в этом классе @ DeForum.ru

пишу клас где загружают рисунок в мувик, и при этом показывают сколько процентов загрузили и т.д., но сейчас не об этом

есть следующая задача, нужно как то обратится к функции класа из объекта, в котором происходят действия, помогите с синтаксисом. Привожу отрывок кода:

Код:

class ImageLoader extends MovieClip {
   var loader:MovieClipLoader;
   var listener:Object;
   //
   function ImageLoader(imgURL, target) {
  //
  this.loader = new MovieClipLoader();
  this.listener = {};
  //
  this.loader.addListener(listener);
  this.loader.loadClip(imgURL, target);
  //
  this.listener.onLoadStart = function():Void  {
     // !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
     // vot kak eto vizvat'?
     loadIsStart();


  };
   }
   //
   //
   private function loadIsStart():Void {
  trace("ta pofig chto, lij by vyzyvalas' funkcyya")
   }
   //
}

тоесть, нужно вызвать функцию loadIsStart() при начале загрузки.

Три варианта на выбор:

1) Сделать слушателем сам экземпляр класса.

Код:

   
      function ImageLoader(url:String, target:MovieClip)
      {
         loader = new MovieClipLoader();
         loader.addListener(this);
         loader.loadClip(url, target);
      }
      
      function onLoadError()
      {
         trace("error");
      }

2) Создать локальную ссылку на экземпляр класса (можно записать ее значение в Listener).

Код:

      function ImageLoader(url:String, target:MovieClip)
      {
         var me = this;
         
         listener = new Object()
         listener.onLoadError = function()
         {
            me.onError();
         }
         loader = new MovieClipLoader();
         loader.addListener(listener);
         loader.loadClip(url, target);
      }
      
      function onError()
      {
         trace("error");
      }

3) Воспользоваться утилитой Delegate

Код:

      function ImageLoader(url:String, target:MovieClip)
      {
         listener = new Object();
         listener.onLoadError = mx.utils.Delegate.create(this, onError);
         loader = new MovieClipLoader();
         loader.addListener(listener);
         loader.loadClip(url, target);
      }
      
      function onError()
      {
         trace("error");
      }

3 Сообщения: 37 Зарегистрирован: 06.01.07

sudya, я может конечно чего и не понимаю, но зачем делать надстройку над классом MovieClipLoader, который сам по себе полностью обеспечивает всю функциональность, которая Вам нужна?

DeДверь
Логин:
Пароль:
	Автологин